ABNF Parser Generator

e-mail addresses

When processing HTML forms, a common problem is validating e-mail addresses. This is commonly done with a regular expression and an Internet search will turn up a large number of them in use from simple to complex. For form validation it is probably not a good idea generally to go overboard with the precision of the validation and these regular expressions all serve a useful purpose. However, the specification given in RFC 5322 allows nested, parenthesised comments which have a nested recursive attribute and hence cannot be parsed with a regular expression.

This grammar was put together as an exercise in using Interactive APG. The situation is a common one. The desired grammar is not neatly and competely defined all in one place but is, rather, defined with statements scattered throughout a larger specification. The procedure was to find the required start rule in RFC 5322 - "addr-spec" in this case, which is briefly defined with only four other rules - and paste them into the ABNF grammar textarea. The message log will then list other rule names required but not present. Add them and repeat the procedure until a complete grammar is defined. At this point several unneeded rules will have crept in, which can be discovered in the list of unreferenced rules at the end of the "Grammar Attributes" output. These can then be eliminated, resulting in the grammar given here. (NOTE: Here is a nifty tool for extracting ABNF from RFCs.)

A parser from the grammar given here, together with the JavaScript APG library could serve as a more precise alternative to the regular expression validators.

ABNF Grammar: √ X

addr-spec       =   local-part "@" domain
local-part      =   dot-atom / quoted-string / obs-local-part
domain          =   dot-atom / domain-literal / obs-domain
domain-literal  =   [CFWS] "[" *([FWS] dtext) [FWS] "]" [CFWS]
dtext           =   %d33-90 /          ; Printable US-ASCII
                       %d94-126 /         ;  characters not including
                       obs-dtext          ;  "[", "]", or "\"
qtext           =   %d33 /             ; Printable US-ASCII
                       %d35-91 /          ;  characters not including
                       %d93-126 /         ;  "\" or the quote character
                       obs-qtext
qcontent        =   qtext / quoted-pair
quoted-string   =   [CFWS]
                       DQUOTE *([FWS] qcontent) [FWS] DQUOTE
                       [CFWS]
quoted-pair     =   ("\" (VCHAR / WSP)) / obs-qp
atext           =   ALPHA / DIGIT /    ; Printable US-ASCII
                       "!" / "#" /        ;  characters not including
                       "$" / "%" /        ;  specials.  Used for atoms.
                       "&" / "'" /
                       "*" / "+" /
                       "-" / "/" /
                       "=" / "?" /
                       "^" / "_" /
                       "`" / "{" /
                       "|" / "}" /
                       "~"
atom            =   [CFWS] 1*atext [CFWS]
dot-atom-text   =   1*atext *("." 1*atext)
dot-atom        =   [CFWS] dot-atom-text [CFWS]

obs-local-part  =   word *("." word)
obs-domain      =   atom *("." atom)
obs-dtext       =   obs-NO-WS-CTL / quoted-pair
obs-NO-WS-CTL   =   %d1-8 /            ; US-ASCII control
                   %d11 /             ;  characters that do not
                   %d12 /             ;  include the carriage
                   %d14-31 /          ;  return, line feed, and
                   %d127              ;  white space characters
obs-ctext       =   obs-NO-WS-CTL
obs-qtext       =   obs-NO-WS-CTL
obs-qp          =   "\" (%d0 / obs-NO-WS-CTL / LF / CR)
word            =   atom / quoted-string
FWS             =   ([*WSP CRLF] 1*WSP) /  obs-FWS
                                      ; Folding white space
ctext           =   %d33-39 /          ; Printable US-ASCII
                   %d42-91 /          ;  characters not including
                   %d93-126 /         ;  "(", ")", or "\"
                   obs-ctext
ccontent        =   ctext / quoted-pair / comment
comment         =   "(" *([FWS] ccontent) [FWS] ")"
CFWS            =   (1*([FWS] comment) [FWS]) / FWS
obs-FWS         =   1*WSP *(CRLF 1*WSP)

ALPHA          =  %x41-5A / %x61-7A   ; A-Z / a-z
CR             =  %x0D
                    ; carriage return
                    ; Internet standard newline
;CRLF           = CR LF                    
CRLF           = CR LF / LF / CR                    
DIGIT          =  %x30-39
                    ; 0-9
DQUOTE         =  %x22
                    ; " (Double Quote)
HTAB           =  %x09
                    ; horizontal tab
LF             =  %x0A
                    ; linefeed
SP             =  %x20
VCHAR          =  %x21-7E
                    ; visible (printing) characters
WSP            =  SP / HTAB
                    ; white space

e-mail addresses input

A more thorough study of e-mail addresses can be found here and here and elsewhere no doubt. This grammar given here isn't perfect, but it is a good start if you want to tune it up and create a JavaScript parser that will compete with the PHP parsers cited above. You can select from a tricky few of their test cases here. These are all valid e-mail addresses and should parse correctly.

"first\"last"@example.com
"first@last"@example.com
first.last@[IPv6:::12.34.56.78]
(foo)cal(bar)@(baz)iamcal.com(quux)
cal(woo(yay)hoopla)@iamcal.com
cal(foo\)bar)@iamcal.com

Input String: √ X

Parser Output:

coasttocoastResearchinc

Home of APG - an ABNF Parser Generator ...

Site Map

Interactive APG

ABNF Parser Generator

e-mail addresses

e-mail addresses input