ABNF Parser Generator

IPv6 Grammar

IPv6 addresses are accepted by many, if not most, current Internet protocols. Therefore, parsing them is a low-level requirement of fundamental importance. This grammar captures IPv6 addresses as specified in RFC 2373 with the following features:

facilitates prioritized-choice disambiguation
captures both IPv6 addresses and prefixes from a single start rule
captures all and only correct IPv6 formats in the syntax without further semantic verification
validates integer ranges in the syntax
distinguishs between unicast and multicast addresses in the syntax (anycast addresses are taken from the unicast address space, and are not syntactically distinguishable from unicast addresses)
accepts prefix lengths in the range 1 < length < 127

ABNF Grammar: √ X

IPv6Address   = IPv6Multicast / IPv6Unicast

IPv6Unicast   = FormIPv4 IPv4Address / FormIPv6 ["/" PrefixLength]
FormIPv4      = Compressed4 / Full4
Compressed4   = First4 / HEX4 (Middle41 / Middle42 / Middle43 / Middle44 / Last4)
First4        = COMP *5HEXC
Last4         = *4CHEX COMP
Middle41      = COMP 1*4HEXC
Middle42      = CHEX COMP 1*3HEXC
Middle43      = 2CHEX COMP 1*2HEXC
Middle44      = 3CHEX COMP HEXC
Full4         = 6HEXC

FormIPv6      = Compressed6 / Full6
Compressed6   = First6 / HEX4 (Middle61 / Middle62 / Middle63 / Middle64 / Middle65 / Middle66 / Last6)
First6        = COMP [*6HEXC HEX4]
Last6         = *6CHEX COMP
Middle61      = COMP *5HEXC HEX4
Middle62      = CHEX COMP *4HEXC HEX4
Middle63      = 2CHEX COMP *3HEXC HEX4
Middle64      = 3CHEX COMP *2HEXC HEX4
Middle65      = 4CHEX COMP *1HEXC HEX4
Middle66      = 5CHEX COMP HEX4 
Full6         = 7HEXC HEX4

IPv6Multicast = FormMIPv4 IPv4Address / FormMIPv6 [ "/" PrefixLength ]
FormMIPv4     = CompressedM4 / FullM4
CompressedM4  = MULTIDIG (Middle41 / Middle42 / Middle43 / Middle44 / Last4)
FullM4        = MULTIDIG ":" 5HEXC
FormMIPv6     = CompressedM6 / FullM6
CompressedM6  = MULTIDIG (Middle61 / Middle62 / Middle63 / Middle64 / Middle65 / Middle66 / Last6)
FullM6        = MULTIDIG ":" 6HEXC HEX4

IPv4Address   = INT255 3("." INT255)
PrefixLength  = %x31 %x32 DIGIT7         / ; 1 - 127
                %x31 (%x30 / %x31) DIGIT /
                POS-DIGIT [DIGIT]

; basics
HEX4        = 1*4HEXDIG
COMP        = "::"
HEXC        = 1*4HEXDIG ":"
CHEX        = ":" 1*4HEXDIG
MULTIDIG    = "FF" 2HEXDIG
DIGIT7      =  %x30-37 ; 0-7
POS-DIGIT   =  %x31-39 ; 1-9
INT255      = "2" "5" ("0"/"1"/"2"/"3"/"4"/"5") / ; 0 - 255, allows leading zeros
              "2" ("0"/"1"/"2"/"3"/"4") DIGIT   /
              "1" 2DIGIT                        /
              ["0"] POS-DIGIT DIGIT             /
              ["0" ["0"]] DIGIT                 /
              "0" ["0" ["0"]]

; basics from RFC 4234
DIGIT       =  %x30-39 ; 0-9
HEXDIG      =  %x30-39 / "A" / "B" / "C" / "D" / "E" / "F"

IPv6 Input

NOTE: You MUST click "Configure" and select "ascii" Input Mode. "auto" Input Mode will fail for this input. For a variety of valid IPv6 addresses to try, select from this list.

Input String: √ X

Parser Output:

coasttocoastResearchinc

Home of APG - an ABNF Parser Generator ...

Site Map

Interactive APG

ABNF Parser Generator

IPv6 Grammar

IPv6 Input