ABNF Parser Generator

SDP

Session Description Protocol (SDP) is used by many multimedia protocols to negotiate the client/server parameters to be used in a session. From RFC 4566: "When initiating multimedia teleconferences, voice-over-IP calls, streaming video, or other sessions, there is a requirement to convey media details, transport addresses, and other session description metadata to the participants. SDP provides a standard representation for such information, irrespective of how that information is transported."

This grammar is from RFC 4566, modified for prioritized-choice rule compliance and for simplified URI, IPv4 and IPv6 fields. It matches a superset of valid announcements. Further semantic verification of some fields is needed, especially the URI, IPv4 and IPv6 addresses.

ABNF Grammar: √ X

; SDP ANNOUNCEMENT
announcement        = session-section *media-section

; SESSION SECTION
session-section     = (%x76.3d proto-version CRLF)
                      (%x6f.3d origin-field CRLF)
                      (%x73.3d session-name-field CRLF)
                      [(%x69.3d information-field CRLF)]
                      [(%x75.3d uri-field CRLF)]
                      *(%x65.3d email-field CRLF)
                      *(%x70.3d phone-field CRLF)
                      [(%x63.3d connection-field CRLF)]
                      *(%x62.3d bandwidth-field CRLF)
                      1*(%x74.3d time-fields CRLF)
                      [(%x6b.3d key-field CRLF)]
                      *(%x61.3d attribute-field CRLF)
proto-version       = 1*DIGIT
origin-field        = username SP
                      sess-id SP
                      sess-version SP
                      nettype SP
                      (IPv4Type SP IPv4Unicast  /
                      IPv6Type SP IPv6Unicast   /
                      addrtype SP (FQDN / extn-addr))
session-name-field  = text
information-field   = text
uri-field           = URI-reference
email-field         = email-address
phone-field         = phone-number
connection-field    = nettype SP connection-type
bandwidth-field     = bwtype ":" bandwidth
time-fields         = start-time SP stop-time *(%x72 "=" repeat-fields) [(%x7a "=" zone-adjustments)]
repeat-fields       = repeat-interval SP typed-time 1*(SP typed-time)
zone-adjustments    = time SP ["-"] typed-time *(SP time SP ["-"] typed-time)
key-field           = key-type
attribute-field     = attribute

; MEDIA SECTION
media-section         = (%x6d.3d media-field CRLF)
                        [(%x69.3d information-field CRLF)]
                        *(%x63.3d connection-field CRLF)
                        *(%x62.3d bandwidth-field CRLF)
                        [(%x6b.3d key-field CRLF)]
                        *(%x61.3d attribute-field CRLF)
media-field           = media SP MediaPort ["/" PortCount] SP proto 1*(SP fmt)
media                 = token ;typically "audio", "video", "text", or "application"
fmt                   = token ;typically an RTP payload type for audio and video media
proto                 = token *("/" token) ;typically "RTP/AVP" or "udp"
MediaPort             = 1*DIGIT ; definition in RFC 3986 is not quite the same
PortCount             = POS-DIGIT *DIGIT

; ORIGIN FIELD
username              = non-ws-string ;pretty wide definition, but doesn't include space
sess-id               = 1*DIGIT ;should be unique for this username/host
sess-version          = 1*DIGIT
nettype               = token ;typically "IN"
addrtype              = token ;typically "IP4" or "IP6"

; EMAIL FIELD (see RFC 2822 for definitions)
email-address         = address-and-comment / dispname-and-address / addr-spec
address-and-comment   = addr-spec 1*SP "(" 1*email-safe ")"
dispname-and-address  = 1*email-safe 1*SP "<" addr-spec ">"

; PHONE FIELD
phone-number          = phone *SP "(" 1*email-safe ")" / 1*email-safe "<" phone ">" / phone
phone                 = ["+"] DIGIT 1*(SP / "-" / DIGIT)

; BANDWIDTH FIELD
bwtype                = token
bandwidth             = 1*DIGIT

; TIME FIELD
start-time            = time / "0"
stop-time             = time / "0"
time                  = POS-DIGIT 9*DIGIT
                        ; Decimal representation of NTP time in
                        ; seconds since 1900.  The representation
                        ; of NTP time is an unbounded length field
                        ; containing at least 10 digits.  Unlike the
                        ; 64-bit representation used elsewhere, time
                        ; in SDP does not wrap in the year 2036.
repeat-interval       = POS-DIGIT *DIGIT [fixed-len-time-unit]
typed-time            = 1*DIGIT [fixed-len-time-unit]
fixed-len-time-unit   = %x64 / %x68 / %x6d / %x73

; KEY FIELD
key-type              = %x70.72.6f.6d.70.74     /         ; "prompt"
                        %x63.6c.65.61.72.3a text /        ; "clear:"
                        %x62.61.73.65.36.34.3a base64  /  ; "base64:"
                        %x75.72.69.3a URI-reference       ; "URI: uri-reference:"
base64                = *base64-unit [base64-pad]
base64-unit           = 4base64-char
base64-pad            = 2base64-char "==" / 3base64-char "="
base64-char           = ALPHA / DIGIT / "+" / "/"

; ATTRIBUTE FIELD
attribute             = (att-field ":" att-value) / att-field
att-field             = token
att-value             = byte-string

; CONNECTION FIELD
connection-type       = IPv6Connection / IPv4Connection / any-connection
any-connection        = addrtype SP (FQDN / extn-addr)
FQDN                  = 4*(alpha-numeric / "-" / ".") ; fully qualified domain name as specified in RFC 1035 (and updates)
extn-addr             = non-ws-string ; Generic for other address families

; IPv4 CONNECTIONS
IPv4Connection  = IPv4Type SP (IPv4MultiCon / IPv4Unicast)
IPv4Type        = "IP4"
IPv4MultiCon    = IPv4Multicast "/" ttl [ "/" AddressCount ]
ttl             = (POS-DIGIT *2DIGIT) / "0"
AddressCount    = POS-DIGIT *DIGIT

; IPv6 CONNECTIONS - differs from IPv6Address in that prefix lengths are not allowed
IPv6Connection  = IPv6Type SP (IPv6MultCon / IPv6Unicast)
IPv6Type        = "IP6"
IPv6MultCon     = IPv6Multicast [ "/" AddressCount ]

; generic sub-rules: datatypes
text          = byte-string
                ;default is to interpret this as UTF8 text.
                ;ISO 8859-1 requires "a=charset:ISO-8859-1"
                ;session-level attribute to be used
byte-string   = 1*(%x01-09/%x0B-0C/%x0E-FF) ;any byte except NUL, CR, or LF
non-ws-string = 1*(VCHAR/%x80-FF) ;string of visible characters
token-char    = %x21 / %x23-27 / %x2A-2B / %x2D-2E / %x30-39 / %x41-5A / %x5E-7E
token         = 1*(token-char)
email-safe    = %x01-09/%x0B-0C/%x0E-27/%x2A-3B/%x3D/%x3F-FF
                ;any byte except NUL, CR, LF, or the quoting
                ;characters ()<>
alpha-numeric = ALPHA / DIGIT

; external references:
     ; ALPHA, DIGIT, CRLF, SP, VCHAR: from RFC 4234
     ; URI-reference: from RFC 3986
     ; addr-spec: from RFC 2822

; RFC 3986: must be re-parsed in semantics
;   examples will use APG parser from
;   sample application URI
URI-reference = 1*%d33-127 ; any printing character
                ; URI-reference only appears in uri-field and key-type
                ; and is always terminated with CRLF
dec-octet     = 1*3DIGIT

; IPv4 and IPv6: must be re-parsed in semantics
;   examples will use hand-coded parser in ApgUtilities
IPv4Multicast = INT224 3("." dec-octet)
IPv4Unicast   = dec-octet 3("." dec-octet)
INT224        = ("22" (%d52-57)) / ("23" DIGIT)     ; 224 - 239
IPv6Multicast = "FF" 1*(HEXDIG / ":" / ".")
IPv6Unicast   = 1*(HEXDIG / ":" / ".")

; RFC 2822: with some editing
addr-spec       = local-part "@" domain
local-part      = dot-atom / quoted-string / obs-local-part
domain          = dot-atom / domain-literal / obs-domain
domain-literal  = [CFWS] "[" *([FWS] dcontent) [FWS] "]" [CFWS]
dcontent        = dtext / quoted-pair
dtext           = NO-WS-CTL /
                  %d33-90   /
                  %d94-126

; US-ASCII control characters that do not include
; the carriage return, line feed, and white space characters
NO-WS-CTL       = %d1-8 / %d11 / %d12 / %d14-31 / %d127

; Any character except controls, SP, and specials. Used for atoms
atext           = ALPHA / DIGIT / "!" / "#" / "$" / "%" / "&" / "'" / "*" / "+" / "-" /
                  "/" / "=" / "?" / "^" / "_" / "`" / "{" / "|" / "}" / "~"
atom            = [CFWS] 1*atext [CFWS]
dot-atom        = [CFWS] dot-atom-text [CFWS]
dot-atom-text   = 1*atext *("." 1*atext)

; Non white space controls
; The rest of the US-ASCII characters
; not including "\" or the quote character
qtext           = NO-WS-CTL / %d33 / %d35-91 / %d93-126
qcontent        = qtext / quoted-pair
quoted-string   = [CFWS] DQUOTE *([FWS] qcontent) [FWS] DQUOTE [CFWS]
quoted-pair     = ("\" text) / obs-qp
obs-qp          = "\" (%d0-127)
obs-local-part  = word *("." word)
obs-domain      = atom *("." atom)
word            = atom / quoted-string

; Folding white space
FWS             = ([*WSP CRLF] 1*WSP) / obs-FWS

; The rest of the US-ASCII characters not including "(", ")", or "\"
ctext           = NO-WS-CTL / %d33-39 / %d42-91 / %d93-126
ccontent        = ctext / quoted-pair / comment
comment         = "(" *([FWS] ccontent) [FWS] ")"
CFWS            = *([FWS] comment) (([FWS] comment) / FWS)
obs-FWS         = 1*WSP *(CRLF 1*WSP)

; RFC 4234: with slight editing
SP        =  %x20              ; space
HTAB      =  %x09              ; horizontal tab
DQUOTE    =  %x22              ; " (Double Quote)
CRLF      =  (%x0D %x0A) / %x0A / %x0D ; modified to be forgiving on line ender
ALPHA     =  %x41-5A / %x61-7A ; A-Z / a-z
DIGIT     =  %x30-39           ; 0-9
VCHAR     =  %x21-7E           ; visible (printing) characters
WSP       =  SP / HTAB         ; white space
HEXDIG    =  DIGIT / %d65-70 / %d97-102
POS-DIGIT = %x31-39 ; 1 - 9

SDP Input

This is a sample SDP announcement from RFC 4566.

Input String: √ X

Parser Output:

coasttocoastResearchinc

Home of APG - an ABNF Parser Generator ...

Site Map

Interactive APG

ABNF Parser Generator

SDP

SDP Input