ABNF Parser Generator

URI

Working our way up the chain, the Uniform Resource Indicator (URI) is one of the fundamental building blocks of many Internet protocols. This grammar is taken from RFC 3986.

ABNF Grammar: √ X

URI-reference = URI / relative-ref
URI           = scheme ":" hier-part [ "?" query ] [ "#" fragment ]
hier-part     = ("//" authority path-abempty) / path-absolute / path-rootless / path-empty
scheme        = ALPHA *( ALPHA / DIGIT / "+" / "-" / "." )
authority     = [ userinfo "@" ] host [ ":" port ]
userinfo      = *( unreserved / pct-encoded / sub-delims / ":" )
host          = IP-literal / IPv4Address / reg-name
port          = *DIGIT
IP-literal    = "[" ( IPv6Address / IPvFuture  ) "]"
IPvFuture     = "v" 1*HEXDIG "." 1*( unreserved / sub-delims / ":" )
reg-name      = *( unreserved / pct-encoded / sub-delims )
path-abempty  = *( "/" segment )
path-absolute = "/" [ segment-nz *( "/" segment ) ]
path-rootless = segment-nz *( "/" segment )
path-noscheme = segment-nz-nc *( "/" segment )
path-empty    = "" ; APG designation for empty strings
segment       = *pchar
segment-nz    = 1*pchar
segment-nz-nc = 1*( unreserved / pct-encoded / sub-delims / "@" ) ; non-zero-length segment without any colon ":"
relative-ref  = relative-part [ "?" query ] [ "#" fragment ]
relative-part = "//" authority path-abempty / path-absolute / path-noscheme / path-empty
pchar         = unreserved / pct-encoded / sub-delims / ":" / "@"
query         = *( pchar / "/" / "?" )
fragment      = *( pchar / "/" / "?" )
pct-encoded   = "%" HEXDIG HEXDIG
unreserved    = ALPHA / DIGIT / "-" / "." / "_" / "~"
sub-delims    = "!" / "$" / "&" / "'" / "(" / ")" / "*" / "+" / "," / ";" / "="

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; IPv6 and IPv4 addresses parsed as characters strings
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
IPv6Address   = 1*(HEXDIG / ":" / ".") ; no prefix length allowed
IPv4Address   = dec-octet "." dec-octet "." dec-octet "." dec-octet
dec-octet     = 1*3DIGIT

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; RFC 4234:
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
ALPHA  =  %x41-5A / %x61-7A ; A-Z / a-z
DIGIT       =  %x30-39 ; 0-9
HEXDIG      =  %x30-39 / "A" / "B" / "C" / "D" / "E" / "F"

URI Input

Here is a list of valid URIs taken from RFC 3986. They should all parse correctly.

ftp://ftp.is.co.za/rfc/rfc1808.txt
http://www.ietf.org/rfc/rfc2396.txt
ldap://[2001:db8::7]/c=GB?objectClass?one
mailto:John.Doe@example.com
news:comp.infosystems.www.servers.unix
tel:+1-816-555-1212
telnet://192.0.2.16:80/
urn:oasis:names:specification:docbook:dtd:xml:4.1.2

Here are a few relative references that should also parse correctly.

g:h
g;x?y#s
.
..
../g
../../g

Input String: √ X

Parser Output:

coasttocoastResearchinc

Home of APG - an ABNF Parser Generator ...

Site Map

Interactive APG

ABNF Parser Generator

URI

URI Input